(* The analytic expression for the ((δχ)^2) parameter, see arXiv: 1210.7652 *)
dx2[M_,n_]:=2InverseGammaRegularized[(M/2),1-Erf[(n/(Sqrt[2]))]]
(* The analytic expression for the Figure of Merit for an ellipse, see arXiv: 1210.7652 *)
FoM[Fij_,M_]:=((Det[Fij])^(1/2))((Gamma[(M/2)+1])/(Pi^(M/2)))((dx2[M,2])^(-M/2))

(* Set up a (χ^2) and a Fisher matrix *)
p={x,y};
M=2;
δχ2=dx2[M,2];
σ1=1;
σ2=3;
ρ=8/10;
Fij=Inverse[{{σ1^2,ρ σ1 σ2},{ρ σ1 σ2,σ2^2}}];
chi2=p.Fij.p;

(* These are the limits of the contour *)
limsy={x,y}/.Solve[{chi2==δχ2,D[chi2,x]==0}];
limsx={x,y}/.Solve[{chi2==δχ2,D[chi2,y]==0}];

(* Validate the Fisher matrix *)
(1/2)D[chi2,{p,2}]-Fij
PositiveDefiniteMatrixQ[Fij]

(* Make a contour plot. We want to calculate the area of the gray shaded region, as FoM=1/area *)
ContourPlot[chi2,Flatten[{x,limsx[[All,1]]}],Flatten[{y,limsy[[All,2]]}],FrameStyle->Black,FrameLabel->{"x","y"},ContourStyle->Black,BaseStyle->FontSize->15,Contours->{δχ2},ContourShading->{LightGray,White},Epilog->{{Red,Point[limsx]},{Green,Point[limsy]}}]

(* Calculate the FoM~1/area numerically *)

1/NIntegrate[Boole[chi2<δχ2],Flatten[{x,limsx[[All,1]]}],Flatten[{y,limsy[[All,2]]}],WorkingPrecision->20,PrecisionGoal->20]

(* Calculate the FoM~1/area analytically *)

1/Integrate[Boole[chi2<δχ2],Flatten[{x,limsx[[All,1]]}],Flatten[{y,limsy[[All,2]]}]]
N[%,20]

(* Calculate the area with our expression *)

FoM[Fij,M]
N[%,20]